CU Amiga Super CD-ROM 24/CU Amiga Magazine's Super CD-ROM 24 (1998)(EMAP Images)(GB)(Track 1 of 2)[!][issue 1998-07].iso/CUCD/Utilities/IDerPrefs/IDerPrefs.install

Text File | 1998-05-09 | 5KB | 180 lines

(welcome "Welcome to the IDerPrefs installation utility.")

; (abort #bad-kick)

(if (< (/ (getversion) 65536) 39)
   (abort "You need at least Kickstart 3.0 to use IDerPrefs.")
)
(complete 0)

; Executable
(set #defaultdir
   (askdir
      (prompt  "Where would you like to install the program and it's icon?")
      (help    "The files will be copied directly into the directory you specify.")
      (default "SYS:Prefs/")
   )
)

(set @default-dest #defaultdir)
(if (= (exists @default-dest) 0) (makedir @default-dest))

(copyfiles
   (source  "")
   (choices "IDerPrefs" "IDerPrefs.info")
   (dest    @default-dest)
)
(complete 25)

; AskTool
(if
   (askbool
      (prompt  "Do you want to install the AskTool program also (see help)?")
      (help    "This program lets you optionally be asked at IDer run time which viewing tool to use.")
      (default 1)
   )
   (
     (set asktool-dest
       (askdir
          (prompt  "Copy the AskTool program where?  It must be in your system path or IDer won't be able to find it.")
          (help    "The AskTool program will be copied here.")
          (default "c:")
       )
     )

     (if (= (exists asktool-dest) 0) (makedir asktool-dest))

     (copyfiles
       (source  "")
       (choices "AskTool")
       (dest    asktool-dest)
     )
   )
)


; "Reset to Defaults" config
(if
   (askbool
      (prompt  "Do you want the default config file to be installed (see help)?")
      (help    "This is to enable the Reset to Defaults menu item.  You should install it regardless of whether you already have your own config file installed or not.")
      (default 1)
   )
   (
     (set config-dest
       (askdir
          (prompt  "Copy the default config where?")
          (help    "The file 'def_IDer.prefs' will be copied here.")
          (default "s:")
       )
     )

     (if (= (exists config-dest) 0) (makedir config-dest))

     (copyfiles
       (source  "")
       (choices "def_IDer.prefs")
       (dest    config-dest)
     )

     (tooltype
       (dest (tackon @default-dest "IDerPrefs"))
       (settooltype "DEFNAME" (tackon config-dest "def_IDer.prefs"))
     )
   )
)
(complete 50)

; Catalogs
(set #lang
   (askoptions
      (prompt  "Which languages would you like to install?")
      (help    "Catalogs will be copied to Locale:Catalogs/<language>/IDerPrefs.catalog.  Language catalogs are by members of the Amiga Translators' Organisation.")
      (choices "ÃeÓtina" "Dansk" "Deutsch" "English (built-in)" "Hrvatski" "Italiano" "Português" "Serbian" "Suomi")
      (default 5)
   )
)

(if (= (exists "Locale:Catalogs") 0) (makedir "Locale:Catalogs"))

(set #i 0)
(while
   (set #language
      (select #i "ÃeÓtina" "Dansk" "Deutsch" "English" "Hrvatski" "Italiano" "Português" "Serbian" "Suomi" "")
   )
   (
      (if (AND (IN #lang #i) (<> #language "English"))
        (
          (set #sourcename ("Catalogs/%s/IDerPrefs.catalog" #language))
          (set #destname   (tackon "Locale:Catalogs" #language))
          (copylib
             (source #sourcename)
             (dest   #destname)
          )
        )
      )
      (set #i (+ #i 1))
   )
)
(complete 75)

; Docs
(set docs
   (askchoice
      (prompt  "Which online help(.guide) file would you like to install?")
      (help    "The language you choose will be copied to Help:<language>/IDerPrefs_XXX.guide")
      (choices "English" "Italiano" "Português")
      (default 0)
   )
)

(if (= docs 0)
    (
       (if (= (exists "Help:English") 0) (makedir "Help:English"))

       (copyfiles
          (source  "Docs/")
          (choices "IDerPrefs.guide" "IDerPrefs.guide.info")
          (dest    "Help:English/")
       )

       (tooltype
          (dest (tackon @default-dest "IDerPrefs"))
          (settooltype "HELPNAME" "Help:English/IDerPrefs.guide")
       )
    )
)
(if (= docs 1)
    (
       (if (= (exists "Help:Italiano") 0) (makedir "Help:Italiano"))

       (copyfiles
          (source  "Docs/")
          (choices "IDerPrefs_ITA.guide" "IDerPrefs_ITA.guide.info")
          (dest    "Help:Italiano/")
       )

       (tooltype
          (dest (tackon @default-dest "IDerPrefs"))
          (settooltype "HELPNAME" "Help:Italiano/IDerPrefs_ITA.guide")
       )
    )
)
(if (= docs 2)
    (
       (if (= (exists "Help:Português") 0) (makedir "Help:Português"))

       (copyfiles
          (source  "Docs/")
          (choices "IDerPrefsPortuguese.guide" "IDerPrefsPortuguese.guide.info")
          (dest    "Help:Português/")
       )

       (tooltype
          (dest (tackon @default-dest "IDerPrefs"))
          (settooltype "HELPNAME" "Help:Português/IDerPrefsPortuguese.guide")
       )
    )
)
(complete 100)